Solving Math’s Assignment with Sage

Someone sent me this question:

Solve for the currents in the circult of Figure 2, if E(t)=5H(t-2) and the initial currents are zero. [Hint : Use Lapalce transform to solve this problem.]

So, to solve it, form mesh analysis of two loops. Then, convert them from time domain to complex domain with Laplace transform. Next, solve I1 and I2 with normal algebra. Then only inverse I1 and I2 back to time domain.

Of cause, if you familiar with Sage, you can solve it within 30min (or lesser?).

t = var('t')
s = var('s')
I1 = var('I1')
I2 = var('I2')

E(t) = 5*unit_step(t-2)

E(s) = E(t).laplace(t, s); E(s)
# >> 5*e^(-2*s)/s

equation = [
	-E(s) + I1*20*s + 10*(I1-I2) == 0,
	10*(I2-I1) + I2*30*s + I2*10 == 0 ]

solution = solve(equation, I1, I2); solution
# >> [[I1 == 1/2*(3*s + 2)*e^(-2*s)/(6*s^3 + 7*s^2 + s), I2 == 1/2*e^(-2*s)/(6*s^3 + 7*s^2 + s)]]

# Note that Sage cannot inverse-Laplace time-delay function. So, taking out e^(-2*s)
I1(s) = 1/2*(3*s + 2)/(6*s^3 + 7*s^2 + s)
I2(s) = 1/2/(6*s^3 + 7*s^2 + s)

i1_temp(t) = I1(s).inverse_laplace(s, t); i1_temp
# >>t |--> -1/10*e^(-t) - 9/10*e^(-1/6*t) + 1

i2_temp(t) = I2(s).inverse_laplace(s, t); i2_temp
# >> t |--> 1/10*e^(-t) - 3/5*e^(-1/6*t) + 1/2

# Referring to Table. For G(s)= e^(as)F(s), the inverse is g(t) = f(t-a).
u(t) = unit_step(t)
i1(t) = u(t-2) * ( -1/10*e^(-(t-2)) - 9/10*e^(-1/6*(t-2)) + 1 ) # Answer for i1
i2(t) = u(t-2) * ( 1/10*e^(-(t-2)) - 3/5*e^(-1/6*(t-2)) + 1/2 ) # Answer for i2

p1 = plot(i1(t), 0, 10, color='blue', legend_label='i1(t)')
p2 = plot(i2(t), 0, 10, color='red', legend_label='i2(t)')
show(p1 + p2)

And, the final answers are:

i_1(t) =u(t)\left( \frac{-1}{10}e^{-(t-2)} -\frac{9}{10}e^{-(t-2)/6} +1 \right)
i_2(t) =u(t)\left( \frac{1}{10}e^{-(t-2)} -\frac{3}{5}e^{-(t-2)/6} +\frac{1}{2} \right)

Current I1 and I2 vs time.
Advertisements

Author: zkchong

I have been teaching in university for 7 years and currently a data science engineer at Axiata Digital Advertising, Malaysia.

Leave a Reply

Fill in your details below or click an icon to log in:

WordPress.com Logo

You are commenting using your WordPress.com account. Log Out /  Change )

Google+ photo

You are commenting using your Google+ account. Log Out /  Change )

Twitter picture

You are commenting using your Twitter account. Log Out /  Change )

Facebook photo

You are commenting using your Facebook account. Log Out /  Change )

Connecting to %s